n
;导入网格数据以生成水面
impgrid ww.flac3d
attach face
;为建立水面设置“辅助界面”而分组为水上部分和水下部分
group water_below range group 1 any group 2 any
group water_above range group water_below not
gen separate water_below
interface 1 wrap water_below water_above
set grav 0 -9.81 0
water den 1000
;遍历界面单元节点生成水面
def water_table
p_i=i_head
p_ie=i_elem_head(p_i) ;界面1单元指针赋予p_ie
loop while p_ie # null
;返回界面单元的三个顶点的地址
p_gp1=ie_vert(p_ie,1)
p_gp2=ie_vert(p_ie,2)
p_gp3=ie_vert(p_ie,3)
;以这三个界面单元顶点为水面的三个顶点，生成水面
;interface的节点和网格节点的地址是分别存放的
x1=in_pos(p_gp1,1)
y1=in_pos(p_gp1,2)
z1=in_pos(p_gp1,3)
x2=in_pos(p_gp2,1)
y2=in_pos(p_gp2,2)
z2=in_pos(p_gp2,3)
x3=in_pos(p_gp3,1)
y3=in_pos(p_gp3,2)
z3=in_pos(p_gp3,3)
command
water table face x1,y1,z1 x2,y2,z2 x3,y3,z3
endcommand
p_ie=ie_next(p_ie)
endloop
end
;删除单元组water_below和组water_above，为导入实际的材料分组做准备
model null range group water_below
model null range group water_above
;建立实际材料分组部分
;导入网格数据，重新分组
impgrid ww.flac3d
group soil range group 2 any group 4 any
group rock range group 1 any group 3 any
;执行生成水面的函数water_table
water_table
;删除辅助界面单元
int 1 dele
;彻底删除原先的分组，释放空间
dele range group water_below
dele range group water_above
;施加边界约束条件
fix x y z rang y -0.1 0.1
fix z range x 0 600 z -0.1 0.1
fix x range x -0.1 0.1 z 0 700
fix z range x 0 600 z 699.9 700.1
fix x range x 599.9 600.1 z 0 700
;初始化材料密度: 饱和的和非饱和的
def ini_dens
p_z = zone_head ;将网格单元指针赋为p_z
;循环，并进行判断,如果隶属于组名为“土”的网格单元孔隙水压力不等于0，那么该单元密度为2120,其它单元密度为2020
loop while p_z # null
if z_group( p_z)='soil' then
if z_pp( p_z) # 0.0 then
z_density( p_z) = 2120
else
z_density( p_z) = 2020
endif
endif
if z_group( p_z)='rock' then
if z_pp( p_z) # 0.0 then
z_density( p_z) = 3460
else
z_density( p_z) = 3360
endif
endif
p_z = z_next( p_z)
endloop
end
;执行ini_dens函数
ini_dens
;通过弹性求解生成初始应力场
model elas
pro bulk 1e10 she 1e10 range group soil
pro bulk 1e10 she 1e10 range group rock
solve fo 1e3
;位移和速度归零
ini xdisp 0
ini ydisp 0
ini zdisp 0
ini xvel 0
ini yvel 0
ini zvel 0
;定义材料特性
;冰碛土物理力学参数指标
model mohr
pro bulk 4.0e8 she 2.4e8 co 2.6e5 fric 28.5 ten 1e4 dil 10 range group soil
;强节理化辉长岩物理力学参数指标
pro bulk 8e8 she 6e8 co 4.60e5 fric 37 ten 4e3 dil 15 range group rock
set mech ratio 1.0e-6
solve
